Weird & Wonderful IT

Been having a bit of trouble installing QuickTime silently – kept getting errors on the lines of ‘A Newer Version of QuickTime already exists’, even though the previous version was 6.something. We were trying to install 7.6.8.

It seems like the installer looks in a number of places for this information. We did manage to get the install to work though, using the following script. Hope this will help someone else.

On Error Resume Next
Set obj_shell = CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_LOCAL_MACHINE = &H80000002

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")

DeleteSubkeys HKEY_LOCAL_MACHINE, "Software\Apple Computer, Inc.\QuickTime"
DeleteSubKeys HKEY_CLASSES_ROOT, "Installer\Products\7414007EACC2C134AA50A21B669B87D5"
DeleteFolder ("C:\Program Files\QuickTime")
DeleteFile("C:\Windows\System32\QuickTime.qts")
DeleteFile("C:\Windows\System32\QuickTimeVR.qtx")
WScript.Sleep 60000

path = WScript.ScriptFullName  ' script file name
ScriptPath = Left(path, InstrRev(path, "\"))
instruction = "msiexec /i " & ScriptPath & "QuickTime.msi /qn"
obj_shell.Exec(instruction)
Wscript.Sleep 60000

Sub DeleteSubkeys(HKEY_LOCAL_MACHINE, strKeyPath)
    objRegistry.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubkeys

    If IsArray(arrSubkeys) Then
        For Each strSubkey In arrSubkeys
            DeleteSubkeys HKEY_LOCAL_MACHINE, strKeyPath & "\" & strSubkey
        Next
    End If

    objRegistry.DeleteKey HKEY_LOCAL_MACHINE, strKeyPath
End Sub

Sub DeleteFolder (Path)
 If FSO.FolderExists(Path) = True Then
  FSO.DeleteFolder Path
 End If
End Sub

Sub DeleteFile(Path)
 If FSO.FileExists(Path)= True Then
  FSO.DeleteFile Path
 End If
End Sub

To use:

1. Extract the QuickTime MSI files from the setup package.
2. Save the above script as a VBS file and place in the same folder as the MSI file.
3. Install the AppleApplicationSupport.msi file silently. (msiexec /i AppleApplicationSupport.msi /qn)
4. Run the script.

After 2-3 minutes the latest version of QuickTime should then be installed.

Hope this helps save someone else the frustration.

Maybe in the future Apple will write some better MSI’s. I suppose atleast we should be grateful that they are now MSI!

Be the first to like.

Mark this post as useful.

Unmark this post as useful.